// TypeDefinitions.pas — TmcFontSettings
TmcFontSettings = record
        FFontName : array[1..256] of Char;
        FontSize : integer;
        FontShade : Byte;
        WordCyan, WordMagenta, WordYellow, WordBlack : Word;
        FText : array[1..25] of Char;
        TextMode : Byte; // 0=replace 1=prepend 2=append
        // 19-dec-2004
        HorScale : integer;
        VertScale : integer;
        Track : integer;
        Kern : integer;
        BaseShift : integer;
        // 11-nov-2005
        AddedTextMode : Byte; // 0=same 1=alt1 2=alt2 3=nothing
        // 26-aug-2013
        FColorName : array[1..50] of Char;
        // 6-may-2016
        FontOpacity : Byte;
        // 14-apr-2020
        CombinedFrameShadeRec : TCombinedFrameShadeRec;
        // 1-march-2017
        ShadeRec : TTextShadeRec;
        FrameRec : TTextFrameRec;
        // 26-mars-2017
        StrokeRec : TTextStrokeRec;
        // 3-oct-2021
        Skew : integer;
        Leading : integer;
        // 23-jan-2025
        IsCombinedDateBoxSettings : boolean;
        ReallyUsesCombinedDateBoxSettings : boolean;
        // 11-july-2025
        StylesAttr : TStylesAttributesRec;
        private
        function GetColorName: string;
        function GetCyan: Integer;
        function GetMagenta: Integer;
        function GetYellow: Integer;
        function GetBlack: Integer;
        function GetFontName: string;
        function GetText: string;
        procedure SetColorName(const Value: string);
        procedure SetCyan(const Value: Integer);
        procedure SetMagenta(const Value: Integer);
        procedure SetYellow(const Value: Integer);
        procedure SetBlack(const Value: Integer);
        procedure SetFontName(const Value: string);
        procedure SetText(const Value: string);
        public
        procedure Initialize;
        procedure ReadFromXML(out StylesAdded, StylesRemoved: TmcTextStyle; const node:
            TXmlNode);
        procedure SaveToXML(StylesAdded, StylesRemoved: TmcTextStyle; const node:
            TXmlNode);
        function DoesSomething(StylesAdded, StylesRemoved: TmcTextStyle): Boolean;
        function UsesQuark2017Attr: Boolean;
        property ColorName: string read GetColorName write SetColorName;
        property Cyan: Integer read GetCyan write SetCyan;
        property Magenta: Integer read GetMagenta write SetMagenta;
        property Yellow: Integer read GetYellow write SetYellow;
        property Black: Integer read GetBlack write SetBlack;
        property FontName: string read GetFontName write SetFontName;
        property Text: string read GetText write SetText;
        end;

// TypeDefinitions.pas — TmcFontSettings.GetColorName
function TmcFontSettings.GetColorName: string;
begin
   result := ArrayToString(FColorName);
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetFontName
function TmcFontSettings.GetFontName: string;
begin
   result := ArrayToString(FFontName);
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetText
function TmcFontSettings.GetText: string;
begin
   result := ArrayToString(FText);
end;
 
// TypeDefinitions.pas — TmcFontSettings.Initialize
procedure TmcFontSettings.Initialize;
begin
   self := Default(TmcFontSettings);
   Text := '';
   TextMode := 0;
   AddedTextMode := 0;
   FontName := '';
   FontSize := 800;
   FontShade := 100;
   FontOpacity := 100;
   Cyan := 12;
   Magenta := 34;
   Yellow := 56;
   Black := 78;
   ColorName := 'BLACK:1';
   HorScale := 10000;
   VertScale := 10000;
   Track := 0;
   Kern := 0;
   BaseShift := 0;
   Skew := 0;
   Leading := 0;
 
   self.CombinedFrameShadeRec.Initialize;
   self.ShadeRec.Initialize;
   self.FrameRec.Initialize;
 
   IsCombinedDateBoxSettings := false;
   ReallyUsesCombinedDateBoxSettings := false;
 
   self.StrokeRec.Initialize;
   self.StylesAttr.Initialize;
end;
 
// TypeDefinitions.pas — TmcFontSettings.ReadFromXML
procedure TmcFontSettings.ReadFromXML(out StylesAdded, StylesRemoved:
    TmcTextStyle; const node: TXmlNode);
var
   node2 : TXmlNode;
   s : string;
begin
   self.Initialize;
   if node = nil
      then exit;
 
   s := ''; ReadNodeValue(node, 'StylesAdded', s); StylesAdded := StringToTextStyle(s);
   s := ''; ReadNodeValue(node, 'StylesRemoved', s); StylesRemoved := StringToTextStyle(s);
 
   if tsoHide in StylesAdded
      then exit;
 
// // 19-dec-2004
 
// // 5-june-2015
 
// // 6-may-2016
 
   if StylesAdded <> [] then
      begin
      s:= FontName; ReadNodeValue(node, 'FontName', s); FontName := s;
      ReadNodeValue(node, 'FontSize', FontSize);
      ReadNodeValue(node, 'FontShade', FontShade);
 
      s:= Text; ReadNodeValue(node, 'Text', s); Text := s;
      ReadNodeValue(node, 'TextMode', TextMode);
      ReadNodeValue(node, 'AddedTextMode', AddedTextMode);
 
      ReadNodeValue(node, 'HorScale', HorScale);
      ReadNodeValue(node, 'VertScale', VertScale);
      ReadNodeValue(node, 'Track', Track);
      ReadNodeValue(node, 'Kern', Kern);
      ReadNodeValue(node, 'BaseShift', BaseShift);
 
      ReadNodeValue(node, 'FontOpacity', FontOpacity);
 
      ReadNodeValue(node, 'Skew', Skew);
      ReadNodeValue(node, 'Leading', Leading);
 
      // 26-aug-2013 leave trace that CMYK is now no longer relevant; only ColorName matters
      Cyan := 12;
      Magenta := 34;
      Yellow := 56;
      Black := 78;
      s:= ColorName; ReadNodeValue(node, 'ColorName', s); ColorName := s;
      end;
 
   // minical shade and frame rec, by definition, shaderec is doing something ShadeRec.MinicalType in [5,6,9]
   node2 := node.Find('CombinedFrameShadeRec');
   CombinedFrameShadeRec.ReadFromXML(node2);
   node2 := node.Find('ShadeRec');
   if node2 <> nil
      then ShadeRec.ReadFromXML(node2, CombinedFrameShadeRec);
   node2 := node.Find('FrameRec');
   if node2 <> nil
      then FrameRec.ReadFromXML(node2, CombinedFrameShadeRec);
 
   node2 := node.Find('StrokeRec');
   if node2 <> nil
      then StrokeRec.ReadFromXML(node2);
end;
 
// TypeDefinitions.pas — TmcFontSettings.SaveToXML
procedure TmcFontSettings.SaveToXML(StylesAdded, StylesRemoved: TmcTextStyle;
    const node: TXmlNode);
var
   node2 : TXmlNode;
begin
   node.SetAttribute('rec_type', 'TmcFontSettings');
 
// TextMode: 0=replace 1=prepend 2=append
// // 19-dec-2004
 
// // 11-nov-2005
// AddedTextMode: 0=same 1=alt1 2=alt2 3=nothing
// // 26-aug-2013
 
// // 6-may-2016
 
   node2 := node.AddChild('StylesAdded'); node2.Text := TextStyleToString(StylesAdded);
   node2 := node.AddChild('StylesRemoved'); node2.Text := TextStyleToString(StylesRemoved);
 
   if tsoHide in StylesAdded
      then exit;
 
// // 19-dec-2004
 
// // 5-june-2015
 
// // 6-may-2016
 
   if StylesAdded <> [] then
      begin
      if tsoFontName in StylesAdded then begin node2 := node.AddChild('FontName'); node2.text := FontName; end;
      if tsoFontSize in StylesAdded then begin node2 := node.AddChild('FontSize'); node2.text := IntToStr(FontSize); end;
      if tsoFontShade in StylesAdded then begin node2 := node.AddChild('FontShade'); node2.text := IntToStr(FontShade); end;
      if tsoHorScale in StylesAdded then begin node2 := node.AddChild('HorScale'); node2.text := IntToStr(HorScale); end;
      if tsoVertScale in StylesAdded then begin node2 := node.AddChild('VertScale'); node2.text := IntToStr(VertScale); end;
      if tsoTrack in StylesAdded then begin node2 := node.AddChild('Track'); node2.text := IntToStr(Track); end;
      if tsoKern in StylesAdded then begin node2 := node.AddChild('Kern'); node2.text := IntToStr(Kern); end;
      if tsoBaseShift in StylesAdded then begin node2 := node.AddChild('BaseShift'); node2.text := IntToStr(BaseShift); end;
      if tsoFontOpacity in StylesAdded then begin node2 := node.AddChild('FontOpacity'); node2.text := IntToStr(FontOpacity); end;
      // 3-oct-2021
      if tsoSkew in StylesAdded then begin node2 := node.AddChild('Skew'); node2.text := IntToStr(Skew); end;
      if tsoLeading in StylesAdded then begin node2 := node.AddChild('Leading'); node2.text := IntToStr(Leading); end;
 
      // 26-aug-2013 leave trace that CMYK is now no longer relevant; only ColorName matters
      if tsoFontColor in StylesAdded then
         begin
 
         node2 := node.AddChild('ColorName'); node2.text := ColorName;
         end;
 
      if tsoChangeText in StylesAdded then
         begin
         node2 := node.AddChild('Text'); node2.text := Text;
         node2 := node.AddChild('TextMode'); node2.text := IntToStr(TextMode);
         node2 := node.AddChild('AddedTextMode'); node2.text := IntToStr(AddedTextMode);
         end;
      end;
 
   // minical shade and frame rec, by definition, shaderec is doing something ShadeRec.MinicalType in [5,6,9]
   if CombinedFrameShadeRec.ComboType <> cfsNone then
      begin
      node2 := node.AddChild('CombinedFrameShadeRec');
      CombinedFrameShadeRec.SaveToXML(node2);
      end;
   if (CombinedFrameShadeRec.ComboType in [cfsText, cfsBoxCreate, cfsBoxModify]) then
      begin
      if ShadeRec.DoesSomething then
         begin
         node2 := node.AddChild('ShadeRec');
         ShadeRec.SaveToXML(node2, CombinedFrameShadeRec.ComboType);
         end;
      if FrameRec.DoesSomething then
         begin
         node2 := node.AddChild('FrameRec');
         FrameRec.SaveToXML(node2, CombinedFrameShadeRec.ComboType);
         end;
      end;
 
   if StrokeRec.DoesSomething then
      begin
      node2 := node.AddChild('StrokeRec');
      StrokeRec.SaveToXML(node2);
      end;
end;
 
// TypeDefinitions.pas — TmcFontSettings.DoesSomething
function TmcFontSettings.DoesSomething(StylesAdded, StylesRemoved:
    TmcTextStyle): Boolean;
begin
   result := (StylesAdded + StylesRemoved <> [])
             or self.StrokeRec.DoesSomething or self.StylesAttr.DoesSomething
             or CombinedFrameShadeDoesSomething(self.CombinedFrameShadeRec, self.FrameRec, self.ShadeRec);
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetCyan
function TmcFontSettings.GetCyan: Integer;
begin
   result := WordCyan;
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetMagenta
function TmcFontSettings.GetMagenta: Integer;
begin
   result := WordMagenta;
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetYellow
function TmcFontSettings.GetYellow: Integer;
begin
   result := WordYellow;
end;
 
// TypeDefinitions.pas — TmcFontSettings.GetBlack
function TmcFontSettings.GetBlack: Integer;
begin
   result := WordBlack;
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetColorName
procedure TmcFontSettings.SetColorName(const Value: string);
begin
   StringToArray(Value, FColorName);
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetCyan
procedure TmcFontSettings.SetCyan(const Value: Integer);
begin
   if Value > 65535
      then WordCyan := 65535
      else WordCyan := Value;
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetMagenta
procedure TmcFontSettings.SetMagenta(const Value: Integer);
begin
   if Value > 65535
      then WordMagenta := 65535
      else WordMagenta := Value;
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetYellow
procedure TmcFontSettings.SetYellow(const Value: Integer);
begin
   if Value > 65535
      then WordYellow := 65535
      else WordYellow := Value;
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetBlack
procedure TmcFontSettings.SetBlack(const Value: Integer);
begin
   if Value > 65535
      then WordBlack := 65535
      else WordBlack := Value;
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetFontName
procedure TmcFontSettings.SetFontName(const Value: string);
begin
   StringToArray(Value, FFontName);
end;
 
// TypeDefinitions.pas — TmcFontSettings.SetText
procedure TmcFontSettings.SetText(const Value: string);
begin
   StringToArray(Value, FText);
end;